summaryrefslogtreecommitdiff
path: root/build-support/python-packaging-bootstrap/PKGBUILD
blob: 151a2836db8ff213b87804433abc57a581a23e5c (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# upstream git revision: a6efc98e6cda125be25a45410c45f87a8769ca76

# Maintainer: Erich Eckner <deep42thought at archlinux32 dot org>
# Contributor: Felix Yan <felixonmars@archlinux.org>

# heavily borrowed from python-packagings PKGBUILD

pkgbase=python-packaging-bootstrap
_pkgbase="${pkgbase%-*}"
pkgname=(python-packaging-bootstrap python2-packaging-bootstrap)
pkgver=20.7
pkgrel=1
pkgdesc="Core utilities for Python packages - bootstrap version"
arch=('any')
url="https://github.com/pypa/packaging"
license=('Apache')
makedepends=('python-dephell' 'python-setuptools' 'python2-setuptools' 'python-pyparsing'
             'python2-pyparsing')
checkdepends=('python-pytest' 'python2-pytest' 'python-pretend' 'python2-pretend'
              'python-coverage' 'python2-coverage')
source=("https://github.com/pypa/packaging/archive/$pkgver/$_pkgbase-$pkgver.tar.gz")
sha512sums=('4da8f66af066ac92b47664d21af34a02526cd1639cb766927670bec0ac8c7416116834c847678a29862a46faeda7e2f2393744be315cdfbbb8bd55a04ceb942c')

build() {
  cd packaging-$pkgver
  python setup.py build
  python2 setup.py build
}

check() {
  cd packaging-$pkgver
  python -m pytest
  python2 -m pytest
}

package_python-packaging-bootstrap() {
  depends=('python-pyparsing' 'python-six')
  provides=("python-packaging=$pkgver")
  conflicts=('python-packaging')

  cd packaging-$pkgver
  python setup.py install --root "$pkgdir"
}

package_python2-packaging-bootstrap() {
  depends=('python2-pyparsing' 'python2-six')
  provides=("python2-packaging=$pkgver")
  conflicts=('python2-packaging')

  cd packaging-$pkgver
  python2 setup.py install --root "$pkgdir"
}